Redimensionar ventana

[yasmany]

Hola a todos, una pregunta si es posible solventar.
Intento que mi aplicacion se pueda redimensionar teniendor establecido un parametro base/ mínimo
El tamaño de la GUI es de 620 x 405, y es autoajustable(puede ampliarse con el tamaño que se quiera[ al pasar el mouse por los bordes de la ventana aparece la flechita de doble direccion]) con los elementos que contiene la ventana, claro está que a cada elemento le he ubicado el GuiCtrlSetResizin con los parametros correspondientes.

Bueno en si quisiera vuestra ayuda para saber que parámetros tengo que ubicar para que al redimensionar la ventana a partir del tamaño ya dado no se pueda reducir mas, mas bien solo se amplie/reajuste a un tamaño mayor de la ventana y cuando la quiera ser mas pequeña de las dimensiones 620x405 se atranque en esa cantidad.

OPCION 2
O que solo PERMITA AMPLIAR pero sin que aparescan las flechas en los bordes y que no haya que hacer doble clic en el boton de MAXIMIZAR

Espero haberme hecho entender, espero vuestra ayuda...
Esta es la linea de la interfaz, cabe mencionar que la Gui acepta arrastre de ficheros hacia un Edit.

Código: Seleccionar todo

$interfaz = GUICreate("Mi Aplicacion", 620, 405, -1, -1, $WS_OVERLAPPEDWINDOW, BitOR($WS_EX_WINDOWEDGE, $ws_ex_acceptfiles))

[yasmany]

Alguien Disponible?

[Dany]

Sera asi?

Código: Seleccionar todo

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local Const $Width=620
Local Const $Height=405
Global $interfaz = GUICreate("Mi Aplicacion", $Width, $Height, -1, -1, $WS_OVERLAPPEDWINDOW, BitOR($WS_EX_WINDOWEDGE, $ws_ex_acceptfiles))



GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_GETMINMAXINFO, "_WM_GETMINMAXINFO") ; Monitors resizing of the GUI


    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd


Func _WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam) ; used to limit the minimum size of the GUI
#forceref $hWnd, $Msg, $wParam, $lParam
Local $iWidth = $Width ; minimum width setting
Local $iHeight = $Height ; minimum height setting
If $hWnd =  $interfaz then
Local $tagMaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($tagMaxinfo, 7, $iWidth) ; min width
DllStructSetData($tagMaxinfo, 8, $iHeight) ; min height
DllStructSetData($tagMaxinfo, 9, @DesktopWidth) ; max width
DllStructSetData($tagMaxinfo, 10, @DesktopHeight) ; max height
Return $GUI_RUNDEFMSG
EndIf
EndFunc ;==>_WM_GETMINMAXINFO

Saludos

[yasmany]

Gracias por tu tiempo, Gracias por la ayuda, me ha servido mucho... ESTÁ ESPECTACULAR
Muchas Gracias Dany.
Una pequeño detalle... cuando muestro la ventana esta tiende a reducirse un poquitin cuando lo hago con el mouse en los bordes, será posible evitar eso?

[Dany]

Juega con el código de seguro lo logras. ;)

Sino te respondo mañana.

Saludos

Edit: Ahi esta arreglado (me dio chance de terminarlo de una vez lol)

Código: Seleccionar todo

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Local Const $Width=620
Local Const $Height=405
Global $interfaz = GUICreate("Mi Aplicacion", $Width, $Height, -1, -1, $WS_OVERLAPPEDWINDOW, BitOR($WS_EX_WINDOWEDGE, $ws_ex_acceptfiles))



GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_GETMINMAXINFO, "_WM_GETMINMAXINFO") ; Monitors resizing of the GUI


    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd


Func _WM_GETMINMAXINFO($hWnd, $Msg, $wParam, $lParam) ; used to limit the minimum size of the GUI
#forceref $hWnd, $Msg, $wParam, $lParam
Local Const $iWidth = $Width+16 ; minimum width setting
Local Const $iHeight = $Height+38 ; minimum height setting
If $hWnd =  $interfaz then
Local $tagMaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($tagMaxinfo, 7, $iWidth) ; min width
DllStructSetData($tagMaxinfo, 8, $iHeight) ; min height
DllStructSetData($tagMaxinfo, 9, @DesktopWidth) ; max width
DllStructSetData($tagMaxinfo, 10, @DesktopHeight) ; max height
Return $GUI_RUNDEFMSG
EndIf
EndFunc ;==>_WM_GETMINMAXINFO

Saludos

[yasmany]

Gracias Dany !!!
Muy agradecido por tu ayuda, estaba revisando un foro en ingles con respecto al tema.
http://www.autoitscript.com/wiki/Moving ... PopUp_GUIs
Gracias una vez más.