Borrar archivos mas antiguos de 7 dias

[edufe]

Hola a todos,

Quiero hace un programa que me revise los archivos de una carpeta y borre los mas antiguos de 7 días. No se bien como hacerlo me pueden orientar un poco. Llevo poco tiempo con autoit.

Gracias

[Dany]

Puedes hacer algo así.

Código: Seleccionar todo

#include <MsgBoxConstants.au3>
#include <FileConstants.au3>
#include <Date.au3>
#RequireAdmin
Example()

Func Example()
	; Assign a Local variable the search handle of all files in the current directory.
	Local $sDirectory = @TempDir & "\"
	Local $hSearch = FileFindFirstFile($sDirectory & "*.*")

	; Check if the search was successful, if not display a message and return False.
	If $hSearch = -1 Then
		MsgBox($MB_SYSTEMMODAL, "", "Error: No files/directories matched the search pattern.")
		Return False
	EndIf

	; Assign a Local variable the empty string which will contain the files names found.
	Local $sFileName = "", $iResult = 0
	Local $aTime = 0
	Local $iDiff = 0
	While 1
		$sFileName = FileFindNextFile($hSearch)
		; If there is no more file matching the search.
		If @error Then ExitLoop

		$aTime = FileGetTime($sDirectory & $sFileName, $FT_CREATED)
		$iDiff = _DateDiff("D", $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2], _NowCalc())
		If $iDiff > 7 Then
;~ 		ConsoleWrite($sDirectory & $sFileName & @TAB & $iDiff & @CRLF)
			FileDelete($sDirectory & $sFileName)
		EndIf

	WEnd

	; Close the search handle.
	FileClose($hSearch)
EndFunc   ;==>Example

Saludos

[mcr_bkn]

Dany muy util tu condigo y justo me sirve muchas gracias!!! y como seria amigo para agregarle sub carpetas, que ademas de buscar los archivos en la raiz lo haga en sub carpetas.

gracias de ante mano...