creación de menús?

[alexis]

holas, buenas noches.

hay algún tutorial que explique de forma sensilla la creación de los menús?
lo del manual no lo entiendo.

desde ya muchas gracias,

saludos.

[Dany]

Hola Alexis. anoche no pude hacerte el ejemplo. pero aquí esta. espero lo entiendas trate de hacerlo con sonidos en los eventos de los menú para que entiendas mas o menos el orden. también coloque nombres largos a los controles y funciones para que sea mas fácil de entender. cualquier duda pregunta.

Código: Seleccionar todo

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <StaticConstants.au3>


Opt("GUIOnEventMode", 1) ;para trabajar en eventos. ya lo has usado


    Global $hGUI=GUICreate("My GUI menu", 300, 200) ;creamo la qui
    GUISetOnEvent($GUI_EVENT_CLOSE, "Cerrar");Para cerrar al darle a la x de la interfaz

    Local $Menu1 = GUICtrlCreateMenu("Menu1");creamos el primer Menu

    Local $SubMenu1delMenu1 = GUICtrlCreateMenuItem("SubMenu1delMenu1", $Menu1) ;Creamos el submenu 1 para el menu 1
	GUICtrlSetOnEvent($SubMenu1delMenu1, "FuncionSubMenu1delMenu1");Para hacer algo al darle click al submenu1 del menu1 La funciona hace un sonido
    Local $SubMenu2delMenu1 = GUICtrlCreateMenuItem("SubMenu2delMenu1", $Menu1) ;creamos el submenu 2 para el menu 1
    GUICtrlSetOnEvent($SubMenu2delMenu1, "FuncionSubMenu2delMenu1");Para hacer algo al darle click al submenu2 del menu1 La funciona hace dos sonido

    Local $Menu2 = GUICtrlCreateMenu("Menu2") ;creamos el menu2
    Local $SubMenu1delMenu2 = GUICtrlCreateMenuItem("SubMenu1delMenu2", $Menu2) ;Creamos el submenu 1 para el menu 2
	GUICtrlSetOnEvent($SubMenu1delMenu2, "FuncionSubMenu1delMenu2");Para hacer algo al darle click al submenu1 del menu2 La funciona hace un sonido
    Local $SubMenu2delMenu2 = GUICtrlCreateMenuItem("SubMenu2delMenu2", $Menu2) ;creamos el submenu 2 para el menu 2
    GUICtrlSetOnEvent($SubMenu2delMenu2, "FuncionSubMenu2delMenu2");Para hacer algo al darle click al submenu2 del menu2 La funciona hace dos sonido
    Local $Sub_Menu3delMenu2ConSubMenus = GUICtrlCreateMenu("Recent Files",$Menu2);Creamos el submenu 3 para el menu2 que puede tener otros submenus
    Local $SubMenu1delsubmenu3delmenu2 = GUICtrlCreateMenuItem("SubMenu1delsubmenu3delmenu2", $Sub_Menu3delMenu2ConSubMenus) ;creamos el submenu1 del submenu3 del menu2
    GUICtrlSetOnEvent($SubMenu1delsubmenu3delmenu2, "FuncionSubMenu1delsubmenu3delmenu2");Para hacer algo al darle click al submenu1 del submenu3 del menu2 La funciona hace tres  sonido

;el menu1 y el menu2 son los que por defecto se ven en la interfaz. al darle click ellos muestran sus submenus
;el submenu3 del menu dos muestra sus submenus cuando tienes el mouse sobre el.

    GUISetState(@SW_SHOW)

 While Sleep(100)

 WEnd

Func FuncionSubMenu1delMenu1()
	Beep(400,300)
EndFunc

Func FuncionSubMenu1delMenu2()
	Beep(500,300)
EndFunc

Func FuncionSubMenu2delMenu2()
	Beep(500,300)
	Beep(500,300)
EndFunc

Func FuncionSubMenu2delMenu1()
	Beep(400,300)
	Beep(400,300)
EndFunc


Func FuncionSubMenu1delsubmenu3delmenu2()
	Beep(400,300)
	Beep(400,300)
	Beep(400,300)
EndFunc

Func Cerrar()
	Exit
EndFunc

Saludos

[alexis]

exelente!
parece medio complicado pero están muy claros. igual cuando los empieze a aplicar los voy a comprender del todo.

como siempre un estupendo trabajo y una gran ayuda,
muchas gracias ☺

saludos.

[Dany]

De nada bro.

Saludos