Bloquear imagenes en IE?

[emma93]

Bueno, acá les vengo con una duda.

Como puedo hacer para que por ejemplo, un objeto creado "IE", lea todo el contenido de una web excepto las imagenes y animaciones?

Porque quiero, que al cargar una web solo se vean las cosas básicas (texto), pero no quiero que termine a cargar todas las imagenes y animaciones (publicidad) que tiene ésta web.

Espero que me puedan ayudar.

Un salu2, fekaa.-

[Chefito]

Puede que te interese este post:
http://www.emesn.com/autoitforum/viewto ... orer#p2676

En tu caso, tendrías que cambiar los valores del registro "Display Inline Images" y "Play_Animations" a "no", los cuales se encuentran en la clave del registro indicada en el post anterior.

Pero ten cuidado....que los cambios realizados en el registro, también afectan a las demás instancias del Internet Explorer.
Una solución sería almacenar los valores iniciales del registro, cambiarlos a "no" justo antes de cargar la página web, cargar la página web,y cambiar otra vez los valores del registro a su valor inicial .

Un ejemplo de lo anterior:

Código: Seleccionar todo

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <WindowsConstants.au3>

$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580, _
        (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
        $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS)
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 40, 600, 360)
$GUI_Button = GUICtrlCreateButton("Cargar página", 230, 420, 100, 30)

GUISetState()       ;Show GUI

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $GUI_Button
			Local $imagenes=RegRead("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Display Inline Images")
			Local $animaciones=RegRead("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Play_Animations")
			RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Display Inline Images","REG_SZ","no")
			RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Play_Animations","REG_SZ","no")
            _IENavigate ($oIE, "http://www.msn.com")
			RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Display Inline Images","REG_SZ",$imagenes)
			RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\Main","Play_Animations","REG_SZ",$animaciones)
    EndSelect
WEnd

GUIDelete()

Exit

Saludos .

[emma93]

Funciona perfecto.

Gracias che! Un abrazo :)

Fekaa.-