Autoit.ES

Código: Seleccionar todo

;Aqui 1.-         1111111111111111111111111111111111111
		$Ventana="Process";"El titulo de la ventana del programa"
			MsgBox(0,"Activando ventana","En seguida",1)
			WinActivate($Ventana) ; se pueden crear el envio de teclas y ratón con el grabador de Macros
			WinWaitActive($Ventana,"",5) ;espera 5 segundos por la ventana a que esté activa
;Aqui 2.-         222222222222222222222222222222222
			Sleep(2000) ; espera de 2 segundos
			Send("^f")  ;envio la tecla alt + a al interface del programa activo
;Aquí 3.-         333333333333333333333333333333333
			Sleep(1000) ; espera de 1 segundo
			MouseClick("left",400,400) ; hacer click en las coordenadas 400 400

Código: Seleccionar todo

;Creditos BasicOs - Autoit.es
; Hello World - O programa muy básico para controlar un interface
;Crea un formulario con un botón para iniciar las acciones necesarias para el bot
; Envia una tecla a la interface y un click de ratón a unas coordenadas (atención a las coordenadas relativas o absolutas en OPT)
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
HotKeySet("{ESC}", "Salir")
GUICreate("Mi primer Robot", 264, 175)
GUICtrlCreateLabel("Poner una información adicional aqui mismo. ESC para salir", 30, 40, 200, 50)
$Button1 = GUICtrlCreateButton("Arrancar el Robot", 120, 120, 120, 25)
GUISetState(@SW_SHOW)

Opt("SendKeyDelay", 50)
Opt("SendKeyDownDelay", 100)

While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			$Ventana="Process";"El titulo de la ventana del programa"
			MsgBox(0,"Activando ventana","En seguida",1)
			WinActivate($Ventana) ; se pueden crear el envio de teclas y ratón con el grabador de Macros
			WinWaitActive($Ventana,"",5) ;espera 5 segundos por la ventana a que esté activa
			Sleep(2000)

			Send("^f")  ;envio la tecla alt + a al interface del programa activo
			Sleep(1000)

			MouseClick("left",400,400) ; hacer click en las coordenadas 400 400
	EndSwitch
WEnd

Func Salir()
	Exit
EndFunc

Código: Seleccionar todo

; Espera hasta que algo cambia en la región 0,0 a 50,50

; Consigue el checksum inicial
$checksum = PixelChecksum(0,0, 50,50)

;Se espera a que la región cambie, la región es chequeada cada 100ms para reducir carga de CPU
While $checksum = PixelChecksum(0,0, 50, 50)
  Sleep(100)
WEnd

MsgBox(0, "Aviso de cambio", "Algo ha cambiado en la región de la pantalla!")

Código: Seleccionar todo

; ===================================================================================
; _findchecksum UDF v1 - June 24, 2007
; Written by Andy Flesner
; ===================================================================================
#cs
Syntax is as follows: _findchecksum($checksum, $width, $height, $pcolor, $x = 0, $y = 0, $d_width = @DesktopWidth, $d_height = @DesktopHeight)

$checksum - the checksum to search for
$width - the width of the checksum area
$height - the height of the checksum area
$pcolor - the pixel color of the top left pixel of the checksum object
$x - the starting x coordinate
$y - the starting y coordinate
$D_Width - Width of the total search area, default is desktop resolution width
$D_Height - Height of the total search area, default is desktop resolution height

The function returns the x and y coordinates of the upper left corner where the checksum
is found as an array.  For Example:

	$coordinates = _findchecksum($checksum, $width, $height, $pcolor)

The x coordinate would be $coordinates[0] and the y coordinate would be $coordinates[1].

If the coordinates are not found, the function will return a value of 0.
#ce
; ===================================================================================

Func _findchecksum($checksum, $width, $height, $pcolor, $x = 0, $y = 0, $d_width = @DesktopWidth, $d_height = @DesktopHeight)
    $current_y = $d_height - 1
    While 1
        $xy = PixelSearch($x, $y, $d_width - 1, $current_y, $pcolor)
        If @error And $current_y = ($d_height - 1) Then
            Return 0
        ElseIf @error Then
            $x = 0
			$y = $current_y + 1
            $current_y = ($d_height - 1)
        ElseIf $checksum = PixelCheckSum($xy[0], $xy[1], $xy[0] + $width, $xy[1] + $height) Then
            Return $xy
        Else
            $x = $xy[0] + 1
			$y = $xy[1]
			$current_y = $y
        EndIf
    WEnd
EndFunc