http://msdn.microsoft.com/en-us/library ... 85%29.aspx
Necesita Windows Script 5.6 o superior pero será raro que no lo tengáis ya en el sistema.
Funcionalidad:
.- Acceso directo a las cadenas por nombre identificativo
.- Uso de StringFormat para insertar variables en su posición correcta y hacer textos de varias líneas.
- CapturaEsp.PNG (20.37 KiB) Visto 2163 veces
- CapturaEng.PNG (20.85 KiB) Visto 2163 veces
Uso tres idiomas muy utilizados: español, inglés y haxor
El selector de idioma es muy simple (aunque sí mira qué lenguajes hay disponibles), no mira codificaciones estándar ni cosas de esas, lo importante es el uso del diccionario para usar las cadenas.
Con el diccionario accedemos a las cadenas por un nombre identificativo que les asignamos, de esta manera no importa el orden en que están en al archivo, o si sobran o faltan cadenas (si falta saldrá en blanco en este ejemplo simple, luego comento cómo mejorar ese comportamiento).
Si con un diccionario quiero acceder a la cadena "tituloGUI" simplemente se hace dict.item("tituloGUI"). Lo bueno del asunto es que los objetos COM pueden tener métodos por defecto, y el de Scripting.Dictionary es item(), así que se puede hacer dict("tituloGUI"), lo que simplifica el código y aunmenta la legibilidad, pero recordar que dict no es una función, en realidad estamos llamando a su método item()
He usado StringFormat sólo cuando es necesario (para insertar variables o para cadenas multilínea). Se podría usar para todas las cadenas para hacerlo siempre igual, pero creo que es una sobrecarga innecesaria.
Este es el código, luego comento alguna mejora:
Código: Seleccionar todo
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 3 -w 4
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly
#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>
;Variables para manejo de idioma
Global $IdiomaPath = @ScriptDir & "\Lenguajes.config"
Global $IdiomaLista = "", $Idioma, $idiDict, $idiIni, $idiIniSecciones
$idiIniSecciones = IniReadSectionNames($IdiomaPath)
For $i = 1 To $idiIniSecciones[0]
$IdiomaLista &= $idiIniSecciones[$i] & "|"
Next
;Hago un simple GUI para seleccionar idioma, en este uso... ningún idioma ;-)
Global $lista, $listIdioma, $btnSeguir, $nMsg
Global $guiSelIdioma = GuiCreate("", 180, 150)
$listIdioma = GuiCtrlCreateList("", 40,30, 100,50)
GuiCtrlSetData(-1, $IdiomaLista, "ESPAÑOL")
$btnSeguir = GUICtrlCreateButton("", 40,90, 100,40, $BS_ICON)
GUICtrlSetImage(-1, @WindowsDir & "\System32\shell32.dll", -138, 1) ; 138,145,177
GUISetState()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit ;Ha cancelado desde la selección de idioma
Case $btnSeguir
$Idioma = GuiCtrlRead($listIdioma)
ExitLoop
EndSwitch
WEnd
GUIDelete($guiSelIdioma)
;Preparamos el diccionario de idioma
$IdiDict = ObjCreate("Scripting.Dictionary")
$idiIni = IniReadSection($IdiomaPath, $Idioma)
For $i = 1 To $idiIni[0][0]
$IdiDict.Add($idiIni[$i][0], $idiIni[$i][1])
Next
$idiIni = 0 ;Eliminamos la matriz para ahorrar memoria, importante en programas muy grandes con muchos textos
;;;; Este GUI es multilenguaje
Global $guiMultiLengu, $btnMensaje, $btnSalir
$guiMultiLengu = GuiCreate($idiDict("tituloGUI"), 400,140)
GuiCtrlCreateLabel(StringFormat($idiDict("lblOrdeChulo"), @UserName), 20,20, 300, 20)
GUICtrlSetFont(-1, 12, 800)
$btnMensaje = GuiCtrlCreateButton($idiDict("btnMEnsaje"), 140,60, 120,30)
$btnSalir = GuiCtrlCreateButton($idiDict("btnSalir"), 320,100, 60,30)
GUICtrlSetFont(-1, -1, 800)
GUISetState()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE, $btnSalir
$IdiDict.RemoveAll()
$IdiDict = 0
Exit
Case $btnMensaje
MsgBox(64, $idiDict("tituMsgBox"), StringFormat($idiDict("textoMsgBox")))
EndSwitch
WEnd
Lenguajes.zip- (512 Bytes) Descargado 198 veces
Este código de ejemplo aunque es totalmente funcional no mira muchos errores, por ejemplo que no exista el archivo de idiomas o que nos hayan pasado uno donde falte alguna cadena.
Una buena solución para esto es tener un idioma por defecto, que no se lea del archivo externo de idiomas externo, sino que esté en el mismo exe (instalado con un FileInstall, pero este archivo SOLO tendría un idioma) o se asigna a mano cada cadena en código, por ejemplo:
$IdiDict.Add("tituloGUI", "Estás viendo el GUI en español")
Después se reactualiza el diccionario con el idioma que elija el usuario. De esta manera si falta alguna cadena al menos saldrá la del idioma por defecto, y si no hay archivo de idioma podemos ignorar la selección de idioma y mostramos el lenguaje por defecto.
Para actualizar un valor ya asignado del diccionario no se hace con Add(), pues eso es para crear pares clave-valor nuevos. Si ya hemos asignado un idioma por defecto el bucle para reasignar valores se haría así:
Código: Seleccionar todo
$idiIni = IniReadSection($IdiomaPath, $Idioma)
For $i = 1 To $idiIni[0][0]
$IdiDict.item($idiIni[$i][0]) = $idiIni[$i][1]
Next
Las cadenas que falten saldrán en el idioma por defecto.
